Here is one that I did just for testing. It takes a URL with a query parameter, which lets me use the same macro to generate a set of pages. The parameter tells the macro what to spit out.
//
// This macro generates a number of pages, using a Page=xx query parameter,
// that are loaded into the display frame of the main web page.
//
Class=[NonFinal]
ClassPath MEng.User.CMLBin.Secure.GenPage;
ParentClass MEng.System.CQC.Runtime.CMLBinBase;
EndClass;
Imports=
MEng.System.Runtime.MemBuf;
MEng.System.Runtime.StringOutStream;
MEng.System.CQC.Runtime.SimpleFldClient;
EndImports;
Members=
// For formatting our contents into
StringOutStream m_Body;
// For getting field values
SimpleFldClient m_FldIO;
EndMembers;
// Private helper methods
Methods=[Private,Final]
// Generates any common opening body content
Method GenHeader([In] String PageRequested)
Begin
// Spit out the common page name at the top
m_Body.FmtStr("<html><body><blockquote><p align='left'>");
m_Body.FmtStr("<u><font face='Berlin Sans FB Demi' size='4'>");
m_Body.FmtStr(PageRequested);
m_Body.FmtStr(" ");
m_Body.FmtStr(" ");
m_Body.FmtStr("</font></u></p>");
EndMethod;
// Generates any common closing body content
Method GenFooter()
Begin
m_Body.FmtStr("</blockquote></html></body>");
EndMethod;
// Some helpers for generating tables
Method EndTable()
Begin
m_Body.FmtStr("</table></font></blockquote>");
EndMethod;
Method StartTable()
Begin
m_Body.FmtStr("<blockquote><font face='Berlin Sans FB Demi' size='4'>");
m_Body.FmtStr("<table border='1' cellspacing='1' width='78%'>");
EndMethod;
Method DoRow([In] String Prefix, [In] String Value)
Begin
Locals=
String ExpVal;
EndLocals;
m_Body.FmtStr("<tr><td align='right' width='185' bgcolor='#99CCFF'>");
m_Body.FmtStr("<font face='Berlin Sans FB'>");
m_Body.FmtStr(Prefix);
m_Body.FmtStr(":</font></td>");
m_Body.FmtStr("<td><font face='Berlin Sans FB'> ");
m_FldIO.ReplaceFldTokens(Value, ExpVal);
m_Body.FmtStr(ExpVal);
m_Body.FmtStr("</font></td></tr>");
EndMethod;
// These methods generate the various pages that can be requested
Method GenAudioPage()
Begin
EndMethod;
Method GenHomePage()
Begin
EndMethod;
Method GenLightCell([In] String Title
, [In] String Field)
Begin
Locals=
Card4 PercentLvl;
EndLocals;
PercentLvl := m_FldIO.ReadCardField("Lighting", Field);
// Do the title text for this one
m_Body.FmtStr("<td align='center' height='100' width='120'>");
m_Body.FmtStr("<font face='Berlin Sans FB'>");
m_Body.FmtStr(Title);
m_Body.FmtStr("</font><p><img border='0' src='");
// Spit out an off or on light image based on state
m_Body.FmtStr("/CQCImg/System/Hardware/Icons/Light%20");
If (PercentLvl > 0)
m_Body.FmtStr("On");
Else
m_Body.FmtStr("Off");
EndIf;
// And put the percent level out to its right
m_Body.FmtStr(".png' width='48' height='48' align='middle'>");
m_Body.FmtCard4(PercentLvl);
m_Body.FmtStr("%</td>");
EndMethod;
Method GenLightingPage()
Begin
//
// We have a three cell table first, which shows the status
// of each light. So spit out the opening table stuff, then
// we call a helper for each cell since only the name of the
// field changes.
//
m_Body.FmtStr("<table border='0' cellpadding='0' ");
m_Body.FmtStr("cellspacing='0' width='70%'><tr>");
// Do the three lighting groups
GenLightCell("Bedroom", "BedLamp");
GenLightCell("Home Theater", "HTLights");
GenLightCell("Kitchen", "DRTable");
// Now close off the table
m_Body.FmtStr("</tr></table>");
EndMethod;
Method GenVideoPage()
Begin
EndMethod;
Method GenWeatherPage()
Begin
// Spit out the appropriate weather channel image
m_Body.FmtStr("<img align='middle' ");
m_Body.FmtStr("src='/CQCImg/System/Weather/Weather Channel/64x64/");
m_Body.FmtCard4(m_FldIO.ReadCardField("Weather", "CurIcon"));
m_Body.FmtStr(".png'>");
// Put the condition text to the right of it
m_Body.FmtStr("<font face='Berlin Sans FB' size='4'> ");
m_Body.FmtStr(m_FldIO.ReadStringField("Weather", "CurCondText"));
// And generate a table of other values underneath
StartTable();
DoRow("As Of:", "$(Weather.ForecastAsOf)");
DoRow("Current Temp", "$(Weather.CurTemp)F");
DoRow("Humidity", "$(Weather.CurHumidity)%");
DoRow("Wind Speed", "$(Weather.CurWindSpeed)mph - $(Weather.CurWindDir)");
DoRow("Barometer", "$(Weather.CurBaro) - $(Weather.CurBaroTrend)");
EndTable();
EndMethod;
EndMethods;
// Overrides of virtual methods in our base class
Methods=[Public,Final,Overrides]
// The method called by the web server to generate page content
Method ProcessReq( [Out] MemBuf ToFill
, [Out] Card4 ContLen
, [Out] String ContType
, [Out] String RepText
, [In] Boolean IsGet) Returns Card4
Begin
Locals=
String PageRequested;
EndLocals;
//
// Get the value for the ReqPage query parameter that was
// part of the URL that triggered us. Our parent class provides
// access to the values by their key name.
//
If (!FindReqValue("ReqPage", PageRequested))
ContLen := This.BuildErrReply
(
404
, "The URL did not include the required ReqPage= value"
, ContType
, ToFill
);
RepText := "Bad Request";
Return 404;
EndIf;
Try
//
// Generate any common opening stuff. They all have have a
// title, which is just the requested page text.
//
GenHeader(PageRequested);
// Generate the requested page
If (PageRequested = "Audio")
GenAudioPage();
ElseIf (PageRequested = "Home")
GenHomePage();
ElseIf (PageRequested = "Lighting")
GenLightingPage();
ElseIf (PageRequested = "Video")
GenVideoPage();
ElseIf (PageRequested = "Weather")
GenWeatherPage();
Else
// Make the page name into an error message
PageRequested.Append(" is not a known dynamic page name");
ContLen := BuildErrReply(404, PageRequested, ContType, ToFill);
RepText := "Not Found";
Return 404;
EndIf;
// Generate any common trailing stuff
GenFooter();
EndTry;
Catch
// If anything goes awry, send back the error info
ContLen := This.BuildErrReply
(
500, $Exception.GetErrorText(), ContType, ToFill
);
RepText := "Server Error";
Return 500;
EndCatch;
//
// Ok, now transcode the accumulated text to the output buffer.
// The xcode method will flush the stream for us. Set the
// content type parm to match what we are returning.
//
ContLen := m_Body.XcodeTo(ToFill, "iso-8859-1");
ContType := "text/html;charset=iso-8859-1";
Return 200;
EndMethod;
EndMethods;
Methods=[Public,Final]
Constructor()
Begin
EndConstructor;
//
// We can use the entry point for debugging purposes in the IDE,
// by calling ProcessReq() with dummy info.
//
#BeginDebug
Method Start() Returns Int4
Begin
Locals=
MemBuf ToFill(8192, 64 * 1024);
Card4 ContLen;
String ContType;
String ErrText;
Card4 ResCode;
EndLocals;
AddReqValue("ReqPage", "Weather");
ResCode := ProcessReq(ToFill, ContLen, ContType, ErrText);
Return 0;
EndMethod;
#EndDebug
EndMethods;